Excel vba da açık olan excel kitabı belirlenen saatte kendisini kapatsın.

[can34frht]

Merhaba, yerel ağda ortak kullandığımız bir excel kitabının belirlediğimiz saatte (örnek 17:45) kendisini otomatik kapatmasını sağlayabilecek vba kodları hakkında yardımcı olabilir misiniz?
Teşekkürler.

[a_self_lion]

Merhaba

Excel VBA açın: ALT + F11 , Vba editöründe ThisWorkbook modülüne çift tıklayın. Aşağıdaki vermiş olduğum kodları yapıştırın:

ThisWorkbook içine

Kod: Tümünü seç

Private Sub Workbook_Open()
    ' Çalışma kitabı açıldığında zamanlayıcıyı başlat
    Call ZamanlayiciBaslat
End Sub

Yeni bir modül açın (insert - Module) içine aşağıdaki kodları yapıştırın

Kod: Tümünü seç

Dim KapanisZamani As Date

Sub ZamanlayiciBaslat()
    ' Hedef saat: 17:45 (24 saat formatında)
    KapanisZamani = TimeValue("17:45:00")
    
    ' Şu andan kapanış zamanına kadar süre
    If Now < Date + KapanisZamani Then
        Application.OnTime earliesttime:=Date + KapanisZamani, _
            procedure:="DosyayiKapat", schedule:=True
    End If
End Sub

Sub DosyayiKapat()
    Dim Kaydet As VbMsgBoxResult
    Kaydet = MsgBox("Excel bu dosyayı şimdi kapatacak. Değişiklikleri kaydetmek istiyor musunuz?", vbYesNoCancel + vbQuestion, "Otomatik Kapanış")

    Select Case Kaydet
        Case vbYes
            ThisWorkbook.Save
            Application.Quit
        Case vbNo
            ThisWorkbook.Saved = True
            Application.Quit
        Case vbCancel
            ' Kullanıcı iptal etti, hiçbir şey yapılmaz
    End Select
End Sub

Excel dosyası açıldığında otomatik zamanlayıcı başlar. Saat 17:45 de kullanıcıya mesaj kutusu çıkar.
Evet dosya kaydedilir excel kapanır.
Hayır kaydetmeden kapanır.
İptal kapanmaz.

İyi çalışmalar dilerim.